Назад

   Sync On
Sync Rate 30
 

Rem Создаем матрицу
Make matrix 1,10000,10000,20,20

Rem Текстурируем матрицу
Load image "grass09.bmp",1
Prepare matrix texture 1,1,1,1
Fill matrix 1,0,1

rem Присваиваем координатам вершин матрицы случайные значения
randomize matrix 1,125
 

Rem Основной цикл
Do
set cursor 0,0
print X#
print Y#
print Z#
 Rem  Сохраняем угол объекта
 CameraAngleY# = Camera angle Y()

 Rem  Управление перемещением камеры
 If Upkey()=1
  XTest# = Newxvalue(X#,CameraAngleY#,20)
  ZTest# = Newzvalue(Z#,CameraAngleY#,20)
  If XTest#>0 and XTest#<10000 and ZTest#>0 and ZTest#<10000
   Move camera 10
  Endif
 Endif

 If Leftkey()=1 then Yrotate Camera Wrapvalue(CameraAngleY#-5)
 If Rightkey()=1 then Yrotate Camera Wrapvalue(CameraAngleY#+5)

 X# = Camera position X()
   Z# = Camera position Z()

 Y# = Get ground height(1,X#,Z#)
 Position Camera X#,Y#+35,Z#

 Rem Обновляем экран
 Sync
Loop

Эта программа демонстрирует, как поместить камеру таким образом, чтобы она следовала рельефу местности на матрице.

set cursor 0,0
print X#
print Y#
print Z#

Мы начнем этот урок с объяснения двух полезных текстовых команд "Set Cursor" и "Print". Первая из них помещает курсор в точку на экране с координатами X и Y (параметры команды), с которой мы собираемся начать вывод текста, а вторая выводит текст на экран. Здесь мы используем переменные X#, Y# и Z#. На экран будут выведены значения каждой из них. Если вы хотите вывести на экран текстовую строку, вы должны заключить ее в кавычки.

   If Upkey()=1
  XTest# = Newxvalue(X#,CameraAngleY#,20)
  ZTest# = Newzvalue(Z#,CameraAngleY#,20)
  If XTest#>0 and XTest#<10000 and ZTest#>0 and ZTest#<10000
   Move camera 10
  Endif
 Endif

Эта часть кода ограничивает перемещение камеры для того, чтобы предотвратить выход игрока за пределы матрицы. Переменные Xtest# и Ytest# хранят координаты позиции, в которой мы собираемся установить камеру. Имейте в виду, что значение "20" на самом деле является расстоянием вдвое большим, чем то, на которое мы желаем переместить камеру. Такой прием не подпускает игрока к абсолютной границе матрицы. Выражение сравнения "If" проверяет, не вышли ли новые значения координат за границы матрицы. Матрица занимает площадь в координатах от 0 до 10000 в каждом направлении. Мы используем союз "and" для того, чтобы осуществить более одного сравнения в выражении "If". Если игрок не вышел за пределы указанных границ, то камера перемещается в новое место.

  X# = Camera position X()
  Z# = Camera position Z()

 Y# = Get ground height(1,X#,Z#)
 Position Camera X#,Y#+35,Z#

После того, как камера переместилась, мы сохраняем значения ее координат в переменных X# и Z#. Затем мы получаем координату высоты матрицы в том месте, где расположена камера, и сохраняем это значение в переменной Y#, используя команду "Get Ground Height". В скобках после команды первый параметр - это номер матрицы, для которой мы определяем значение высоты. Следующие два параметра - координаты X и Z, в этой точке мы желаем узнать высоту матрицы. После определения высоты мы устанавливаем камеру на 35 пунктов выше матрицы. Это позволяет перемещаться по матрице на 35 пунктов выше ее рельефа.